0. 环境与预备工作
Arduino IDE + NodeMCU + PIR模块 + Firefox
已经在Arduino IDE上配置好NodeMCU的开发环境。
把PIR模块的信号脚与NodeMCU的D7连接。
1、登入物联网平台登陆台
账号可以是TaoBao。
2、创建产品
3、为产品定义功能
这里的定义功能主要是产品参数。用于设备与网络平台上传递参数。这里默认了多种参数,而且有预置的参数类型
4、创建设备
阿里云物联网平台中,同一款产品可以有多个设备。在这里新建一个设备,名字是Light_1。
5、编写NodeMCU代码
NodeMCU_Aliyun_PirLight.ino
#include <ESP8266WiFi.h>
/* 依赖 PubSubClient 2.4.0 */
#include <PubSubClient.h>
/* 依赖 ArduinoJson 5.13.4 */
#include <ArduinoJson.h>
#define SENSOR_PIN 13
/* 修改1 ------------------------------------------ */
/* 连接您的WIFI SSID和密码 */
#define WIFI_SSID "Nokia7"
#define WIFI_PASSWD "testroom8"
/* 修改1 end--------------------------------------- */
/* 修改2 ------------------------------------------ */
/* 设备证书信息*/
#define PRODUCT_KEY "a1LlrbbOE7d"
#define DEVICE_NAME "Light_1"
#define DEVICE_SECRET "123456"
#define REGION_ID "cn-shanghai"
/* 修改2 end--------------------------------------- */
/* 线上环境域名和端口号,不需要改 */
#define MQTT_SERVER PRODUCT_KEY ".iot-as-mqtt." REGION_ID ".aliyuncs.com"
#define MQTT_PORT 1883
#define MQTT_USRNAME DEVICE_NAME "&" PRODUCT_KEY
/* 修改3 ------------------------------------------ */
#define CLIENT_ID "esp8266|securemode=3,signmethod=hmacsha1,timestamp=1234567890|"
// 请使用以上说明中的加密工具或参见MQTT-TCP连接通信文档加密生成password。
// 加密明文是参数和对应的值(clientIdesp8266deviceName${deviceName}productKey${productKey}timestamp1234567890)按字典顺序拼接
// 密钥是设备的DeviceSecret
#define MQTT_PASSWD "888DB29EED6A21E077AFDE6B25887D5FF592CE08"
/* 修改3 end--------------------------------------- */
#define ALINK_BODY_FORMAT "{\"id\":\"123\",\"version\":\"1.0\",\"method\":\"thing.event.property.post\",\"params\":%s}"
#define ALINK_TOPIC_PROP_POST "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/event/property/post"
unsigned long lastMs = 0;
WiFiClient espClient;
PubSubClient client(espClient);
void callback(char *topic, byte *payload, unsigned int length)
{
Serial.print("Message arrived [");
Serial.print(topic);
Serial.print("] ");
payload[length] = '\0';
Serial.println((char *)payload);
}
void wifiInit()
{
WiFi.mode(WIFI_STA);
WiFi.begin(WIFI_SSID, WIFI_PASSWD);
while (WiFi.status() != WL_CONNECTED)
{
delay(1000);
Serial.println("WiFi not Connect");
}
Serial.println("Connected to AP");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
Serial.print("espClient [");
client.setServer(MQTT_SERVER, MQTT_PORT); /* 连接WiFi之后,连接MQTT服务器 */
client.setCallback(callback);
}
void mqttCheckConnect()
{
while (!client.connected())
{
Serial.println("Connecting to MQTT Server ...");
if (client.connect(CLIENT_ID, MQTT_USRNAME, MQTT_PASSWD))
{
Serial.println("MQTT Connected!");
}
else
{
Serial.print("MQTT Connect err:");
Serial.println(client.state());
delay(5000);
}
}
}
void mqttIntervalPost()
{
char param[32];
char jsonBuf[128];
/* 修改4 ------------------------------------------ */
sprintf(param, "{\"AlarmState\":%d}", digitalRead(13));
/* 修改4 end--------------------------------------- */
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
boolean d = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
Serial.print("publish:0 失败;1成功");
Serial.println(d);
}
void setup()
{
pinMode(SENSOR_PIN, INPUT);
/* initialize serial for debugging */
Serial.begin(115200);
Serial.println("Demo Start");
wifiInit();
}
// the loop function runs over and over again forever
void loop()
{
if (millis() - lastMs >= 5000)
{
lastMs = millis();
mqttCheckConnect();
/* 上报消息心跳周期 */
mqttIntervalPost();
}
client.loop();
if (digitalRead(SENSOR_PIN) == HIGH){
Serial.println("Motion detected!");
delay(2000);
}
else {
Serial.println("Motion absent!");
delay(2000);
}
}
5.1 修改1
第一处修改是WIFI的SSID和密码。
5.2 修改2
第二处修改是设备证书信息。
5.3 修改3
第三处修改是MQTT的ID以及密码。
MQTT_PASSWD密码需要自行生成,这链接可以下载这个密码生成小工具。
https://files.alicdn.com/tpsservice/471c155376d6a88a29c9ad66784e94f0.zip?spm=a2c4g.11186623.2.17.61f6619bQ80OV1&file=471c155376d6a88a29c9ad66784e94f0.zip
这软件解压后,用浏览器打开sign.html。输入相关信息,可生成MQTT_PASSWD。
6、修改PubSubClient.h文件(不修改无法连接Mqtt服务器)
我电脑中的路径是:D:\arduino-1.8.9\portable\sketchbook\libraries\PubSubClient\src\PubSubClient.h
22 -26行修改为:
// MQTT_MAX_PACKET_SIZE : Maximum packet size
#define MQTT_MAX_PACKET_SIZE 1024
// MQTT_KEEPALIVE : keepAlive interval in Seconds
#define MQTT_KEEPALIVE 60
7、测试
7.1 编译下载,Arduino IDE自带的串口监控,可以看到NodeMCU调试信息。
7.2 阿里云IOT平台
可以通过设备->运行状态,观察实时数据。
也可以在监控运维 -> 在线调试。观察NodeMCU的上传信息。
在线调试中,也可以通过左边的界面,往NodeMCU发送信息。
小结:本文介绍了使用NodeMCU接入阿里云物联网平台的一般步骤。可以看到平台的界面是比较友好的,但是阿里云的物联网平台在接入平台时需要设备提供ID和密码。本项目进一步的工作是利用阿里云物联网平台的开发服务生成APP。本文比参考资料[1]的不同点是我个人关注的地方增加了图片以及描述。