Typora 设置字体上色快捷键

1. 安装AutoHotKey

AutoHotkey 是一种免费和开源的微软Windows自定义脚本语言，最初旨在提供简单的键盘快捷键或热键，快速创建宏和软件自动化。

基于成熟的做法，本脚本也采用 AutoHotKey 实现。 AutoHotkey 的使用步骤如下：

下载软件：AutoHotKey
安装软件
创建脚本：新建后缀 .ahk 文件，然后编辑文件，并编写代码。
使用 AutoHotkey 编译代码变成 exe 可执行文件，运行。

下面按照该步骤介绍如何部署本脚本。

2. 部署代码

参考网上其它代码，本脚本进行了改进，主要是不再使用 alt+1~7 来实现选色，而是通过 单按键循环的方式切换文本颜色 ，极大的 提高了效率 。所有代码如下：

; Typora
; 快捷增加字体颜色

AutoTrim, Off	; 关闭忽略空格和tab
#IfWinActive ahk_exe Typora.exe	; 设定在Typora软件被选中时检测
{
	
    ; alt+1 循环选色，行内文字
    !1::timerHandler(1)
	; alt+` 循环选色，段落居中
	!`::timerHandler(2)
	
	; alt+2 强调
    !2::addEnhance()
	; alt+3 强调
    !3::addEnhance2()
	; alt+4 反向强调
    !4::timerHandler(3)


	; alt+w 添加版权说明
	!w::addCopyRight()
	
	!q::addPicCenter()
}

addPicCenter(){
	SendInput {#}pic_center
}

addEnhance(){
	clipboard := "" ; 清空剪切板
	Send ^c 		; 复制
	InputText = %clipboard%
	clipboard = %A_Space%``%InputText%``%A_Space%
	Sleep 50
	Send ^v
}

addEnhance2(){
	clipboard := "" ; 清空剪切板
	Send ^c 		; 复制
	InputText = %clipboard%
	clipboard = %A_Space%==%InputText%==%A_Space%
	Sleep 50
	Send ^v
}

addReverse(){
	clipboard := "" ; 清空剪切板
	Send ^c 		; 复制
	InputText = %clipboard%
	clipboard = %A_Space%<b><span style='color:white;background:black;font-size:24px'>%InputText%</span></b>%A_Space%
	Sleep 50
	Send ^v
}

; 添加版权说明
addCopyRight(){
    clipboard := "" ; 清空剪切板
	; 分割线
	SendInput ---	
	Send {Enter}
	; 版权说明
	clipboard = <center><b> <font face='楷体' size=4, color=red> <br/> 部分图片来源网络，如有侵权请联系我删除。<br/> 如有疑问或错误，欢迎和我私信交流指正。<br/> 版权所有，未经授权，请勿转载！ <br/> </font> <font face='Times' size=3, color=gray> Copyright © %A_Year%.%A_Mon% by Mr.Idleman.&ensp;All rights reserved. </font> </center></b> <br/> 
	Send ^v
	Sleep 100
	Send `n
	Sleep 100
	; 分割线
	SendInput ---	
	Sleep 200
	Send {Enter}
}

; 每次按下刷新定时任务，如果松下alt超过一定时间就退出
timerHandler(flag){
	SetTimer, Check, -1000 ; 在 1000 毫秒后检测.
	addFontColor(flag)
}
Check:
	if(!GetKeyState("Alt", "P")){
		addFontColor(0)
	}
	else{
		SetTimer, Check, -1000
	}

; 快捷增加字体颜色
addFontColor(flag){
	; 设置循环选色数量和颜色类型
	color_num = 9
	colors := ["black", "red", "SEAGREEN", "blue", "DODGERBLUE", "DARKORANGE", "cyan", "purple", "ORCHID"]
	static index := 0
	static InputText := -1
	
	if (!flag){
		index := 0
		clipboard := "" ; 清空剪切板
		InputText = -1
		
		send !
		Sleep 50
		return
	}
	else{
		index += 1
		if (InputText == -1){
			clipboard := "" ; 清空剪切板
			Send ^c 		; 复制
			InputText = %clipboard%
		}
		else{
			Send ^z 		; 撤销
			if(flag==2 || flag==3){
				Send ^z 		; 多撤销一次，取消回车
			}
		}	
	}
	
	
	; 颜色赋值
	color := colors[index]
	if(index==color_num){
		index = 0
	}
	Sleep 50
	if (flag==1){
		clipboard = %A_Space%<b><font color='%color%' size=3 face="">%InputText%</font></b>%A_Space% ; 组合赋值到剪切板
	}
	else if(flag==2){	
		clipboard = %A_Space%<center> <b> <font color='%color%' size=5 face=""> %InputText% </font> </b> </center>%A_Space%<br\>
	}
	else if(flag==3){	
		clipboard = %A_Space%<center> <b> <span style='color:white;background:%color%;font-size:24px'>%InputText%</span> </b> </center>%A_Space%<br\>
	}
	SendInput ^v	; 粘贴
	Sleep 50
	if (flag==2 || flag==3){	; 为了居中显示能够自动渲染，增加一个回车
		SendInput `n
	}
}

先具体介绍如何部署代码：

新建 Typora_color.ahk 文件，复制代码并保存文件：