FIFO (First-In-First-Out) 是一种先进先出的数据交互方式,在数字ASIC设计中常常被使用。FIFO按工作时钟域的不同又可以分为:同步FIFO和异步FIFO。
同步FIFO的写时钟和读时钟为同一个时钟,FIFO内部所有逻辑都是同步逻辑,常常用于交互数据缓冲。异步FIFO的写时钟和读时钟为异步时钟,FIFO内部的写逻辑和读逻辑的交互需要异步处理,异步FIFO常用于跨时钟域交互。
同步FIFO
典型同步FIFO有三部分组成: (1) FIFO写控制逻辑; (2)FIFO读控制逻辑; (3)FIFO 存储实体(如Memory、Reg)。
FIFO写控制逻辑主要功能:产生FIFO写地址、写有效信号,同时产生FIFO写满、写错等状态信号;
FIFO读控制逻辑主要功能:产生FIFO读地址、读有效信号,同时产生FIFO读空、读错等状态信号。
如下图所示,FIFO读写过程的地址控制:
(1)当FIFO初始化(复位)时fifo_write_addr与fifo_read_addr同指到0x0,此时FIFO处于空状态;
(2)当FIFO进行写操作时,fifo_write_addr递增(增加到FIFO DEPTH时回绕),与fifo_read_addr错开,此时FIFO处于非空状态;
(3)当FIFO进行读操作时,fifo_read_addr递增;
FIFO空满状态产生:
为产生FIFO空满标志,引入FIFO Count计数器,FIFO Count寄数器用于指示FIFO内部存储数据个数;
(1)当只有写操作时,FIFO Count加1;只有读操作是,FIFO Count减1;其他情况下,FIFO Count保持;
(2)当FIFO Count为0时,说明FIFO为空,fifo_empty置位;
(3)当FIFO Count等于FIFO_DEPTH时,说明FIFO已满,fifo_full置位;
module sync_fifo(
rst_n ,
clk ,
fifo_wr_en ,
fifo_full ,
fifo_wr_data,
fifo_rd_en ,
fifo_rd_data,
fifo_empty ,
fifo_wr_err,
fifo_rd_err
);
input rst_n ;
input clk ;
input fifo_wr_en ;
input [15:0]fifo_wr_data;
input fifo_rd_en ;
output fifo_full ;
output [15:0]fifo_rd_data;
output fifo_empty ;
output fifo_wr_err;
output fifo_rd_err;
reg [8:0] rdaddress;
reg [8:0] wraddress;
reg [9:0]data_cnt;
assign fifo_full = (data_cnt == 10'h200);
assign fifo_empty = (data_cnt == 10'd0);
assign fifo_wr_err = (data_cnt == 10'h200 && fifo_wr_en);
assign fifo_rd_err = (data_cnt == 10'd00 && fifo_rd_en);
ram ram(
.clock (clk),
.data (fifo_wr_data),
.rdaddress (rdaddress),
.wraddress (wraddress),
.wren (fifo_wr_en),
.q (fifo_rd_data)
);
/*读数据地址生成*/
always@(posedge clk or negedge rst_n)
if(!rst_n)
rdaddress <= 9'b0;
else if(fifo_rd_en && ~fifo_empty)begin
rdaddress <= rdaddress + 1'b1;
end
/*写数据地址生成*/
always@(posedge clk or negedge rst_n)
if(!rst_n)
wraddress <= 9'b0;
else if(fifo_wr_en && ~fifo_full)begin
wraddress <= wraddress + 1'b1;
end
/*fifo 中存储的数据长度计数*/
always@(posedge clk or negedge rst_n)
if(!rst_n)
data_cnt <= 10'b0;
else if(fifo_wr_en && ~fifo_rd_en && ~fifo_full)
data_cnt <= data_cnt + 1'b1;
else if(fifo_rd_en && ~fifo_wr_en && ~fifo_empty)
data_cnt <= data_cnt - 1'b1;
else
data_cnt <= data_cnt;
endmodule