实例需求:数据保存在A列中,需要在其中提取多组数据分别写入B:E列中。如果A列数据以反斜杠结尾,例如A4单元格100g787×1092-白牛皮沙龙纹A/
,提取物料名称时需要去除末尾的反斜杠;对于非反斜杠结尾的数据,则提取减号之后的全部字符(包括反斜杠)作为物料名称。
示例代码如下。
Sub RegExpDemo()
Dim strTxt As String
Dim objRegEx As Object, objMatch As Object
Dim objMH As Object, c As Range
Dim DataRng As Range
Set objRegEx = CreateObject("vbscript.regexp")
objRegEx.Pattern = "^(\d+)g(\d+)×(\d+)-((.*)(?=/$)|(.*?)[^/](?=$))"
objRegEx.Global = True
Set DataRng = Range([a2], Cells(Rows.Count, 1).End(xlUp))
DataRng.Offset(0, 1).Resize(DataRng.Rows.Count, 5).ClearContents
arrCol = Array("C", "D", "E", "B")
For Each c In DataRng
strTxt = c.Value
Set objMatch = objRegEx.Execute(strTxt)
If objMatch.Count > 0 Then
For Each objMH In objMatch
For i = 0 To 3
Cells(c.Row, arrCol(i)).Value = Trim(objMH.submatches(i))
Next
Next
End If
Next
Set objMH = Nothing
Set objMatch = Nothing
Set objRegEx = Nothing
End Sub
【代码解析】
第6行代码使用后期绑定创建正则对象。
第7行代码指定正则匹配字符串。
正则表达式 | 含义 |
---|---|
^ | 匹配开始位置 |
(\d+)g | 匹配一个或者多个数字加字母g ,结果为克重 |
(\d+)×(\d+) | 两个匹配组均匹配一个或者多个数字(宽和长),两者之间为乘号相连接 |
- | 匹配物料名称前面的减号 |
((.*)(?=/$)|(.*?)[^/](?=$)) |
用于匹配物料名称,使用了零宽正向先行断言,此示例的难点在于此处 |
(.*)(?=/$) |
如果以反斜杠结尾,那么提取反斜杠之前的任意字符 |
(.*?)[^/](?=$)) |
如果以非反斜杠字符结尾,那么提取全部字符(可以包含反斜杠) |
第9行代码将数据区域赋值给DataRng
。
第10行代码清空结果单元格区域。
第11行代码指定结果保存的列。
第12行到第22行使用For循环结构处理数据区域单元格。
如果正则可以成功匹配那么第16行到第19行使用For循环结构变量正则匹配结果,写入指定列。
相关博文链接:
VBA之正则表达式(12)-- 格式调整
VBA之正则表达式(13)-- 字符串变换
VBA之正则表达式(14)-- 提取指定位数的数字
VBA之正则表达式(15)-- 提取数字求和
VBA之正则表达式(16)-- 提取非重复值
VBA之正则表达式(17)-- 提取多组数据(去除末尾字符)