参考 Shader 入门精要中第九章内容
Shader "Custom/LightShadow"
{
Properties
{
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {
}
_BumpMap ("Normal Tex", 2D) = "bump" {
}
_BumpScale ("Normal Scale", Range(0, 1)) = 1
_Specular ("Spacular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8, 256))= 20
}
SubShader
{
Tags {
"RenderType" = "Opaque" "Queue" = "Geometry" }
Pass
{
Tags {
"LightMode" = "ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include <Lighting.cginc>
#include <AutoLight.cginc>
#include <UnityCG.cginc>
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
SHADOW_COORDS(4)
};
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
fixed _BumpScale;
fixed4 _Specular;
float _Gloss;
v2f vert(a2v v)
{
v2f o;
//获得裁剪坐标空间的坐标值
o.pos = UnityObjectToClipPos(v.vertex.xyz);
//获得对应 uv 的坐标
o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);
//获得对应的坐标轴 x轴 -> Tangent y轴 -> Binormal z轴 -> Normal
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 litDir = normalize(UnityWorldSpaceLightDir(worldPos));
//获得世界坐标空间的 法向量
fixed3 bump = UnpackScaleNormal(tex2D(_BumpMap, i.uv.zw), _BumpScale);
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
//获得主纹理的颜色
fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//漫反射
fixed3 diffuse = _LightColor0.rgb * albedo * (dot(bump, litDir) * 0.5 + 0.5);
//高光反射 Blinn - Phong 模型
fixed3 halfDir = normalize(viewDir + litDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
//获得衰减值
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4(ambient + (diffuse + specular) * atten, 1);
}
ENDCG
}
Pass
{
Tags {
"LightMode" = "ForwardAdd" }
Blend One One
BlendOp Add
CGPROGRAM
#pragma multi_compile_fwdadd
#pragma vertex vert
#pragma fragment frag
#include <AutoLight.cginc>
#include <Lighting.cginc>
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
SHADOW_COORDS(4)
};
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
fixed _BumpScale;
fixed4 _Specular;
float _Gloss;
v2f vert(a2v v)
{
v2f o;
//获得裁剪坐标空间的坐标值
o.pos = UnityObjectToClipPos(v.vertex.xyz);
//获得对应 uv 的坐标
o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);
//获得对应的坐标轴 x轴 -> Tangent y轴 -> Binormal z轴 -> Normal
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 litDir = normalize(UnityWorldSpaceLightDir(worldPos));
//获得世界坐标空间的 法向量
fixed3 bump = UnpackScaleNormal(tex2D(_BumpMap, i.uv.zw), _BumpScale);
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
//获得主纹理的颜色
fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;
//漫反射
fixed3 diffuse = _LightColor0.rgb * albedo * (dot(bump, litDir) * 0.5 + 0.5);
//高光反射 Blinn - Phong 模型
fixed3 halfDir = normalize(viewDir + litDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
//获得衰减值
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4((diffuse + specular) * atten, 1);
}
ENDCG
}
}
FallBack "Specular"
}