OutSchoolPro的代码实现
个人感觉只要搞清楚那些点积的意义就能写出来
float ndotl = dot(nDirWS , lDirWS); //Lambert 法线方向和光方向做点积
float vdotr = dot(vDirWS , lrDirWS); //Phong 光源的反射方向和视角方向做点积
float vdotn = dot(vDirWS , nDirWS); //CubeMap视角方向和法线方向做点积
fresnel是1减视角方向和法线方向的点积结果
直接光照部分
(basecolor乘Lambert加上高光色乘Phong ) 乘遮挡阴影
环境光部分
(base乘环境三色 再乘 一个漫反射强度 加上cubemap乘fresnel再乘一个高光强度*光滑度贴图)* AO
返回值
直接光+环境光+自发光
Shader "AP1/L10/OutSchoolPro" {
Properties {
[Header(Texture)]
_MainTex ("RGB : 基础颜色 A : 环境光遮蔽" , 2D ) = "white"{}
_NormTex ("RGB : 法线贴图",2D) = "bump"{}
_SpecTex ("RGB : 高光颜色 A : 高光次幂" , 2D) = "gray"{}
_EmitTex ("RGB : 自发光" , 2D) = "black"{}
_Cubemap ("RGB : 环境贴图" , Cube) = "_Skybox"{}
[Header(Diffuse)]
_MainCol ("基本色" , Color) = (0.5 , 0.5 , 0.5 , 1.0)
_EnvDiffInt ("环境漫反射强度" , Range(0 , 1)) = 0.2
_EnvUpCol( "环境水平颜色", Color) = (1.0 , 1.0 , 1.0 , 1.0)
_EnvSideCol ("环境水平颜色", Color ) = (0.5 , 0.5 , 0.5 , 1.0 )
_EnvDownCol ("环境地表颜色" , Color) = (0.0 , 0.0 , 0.0 ,0.0)
[Header(Specular)]
_SpecPow ("高光次幂", Range(1, 90)) = 30
_EnvSpecInt ("环境镜面反射强度", Range(0, 5)) = 0.2
_FresnelPow ("菲涅尔次幂", Range(0, 5)) = 1
_CubemapMip ("环境球Mip", Range(0, 7)) = 0
[Header(Emission)]
_EmitInt ("自发光强度", range(1, 10)) = 1
}
SubShader {
Tags {
"RenderType"="Opaque"
}
Pass {
Name "FORWARD"
Tags {
"LightMode"="ForwardBase"
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
// 追加投影相关包含文件
#include "AutoLight.cginc"
#include "Lighting.cginc"
#pragma multi_compile_fwdbase_fullshadows
#pragma target 3.0
// 输入参数
// Texture
uniform sampler2D _MainTex;
uniform sampler2D _NormTex;
uniform sampler2D _SpecTex;
uniform sampler2D _EmitTex;
uniform samplerCUBE _Cubemap;
// Diffuse
uniform float3 _MainCol;
uniform float _EnvDiffInt;
uniform float3 _EnvUpCol;
uniform float3 _EnvSideCol;
uniform float3 _EnvDownCol;
// Specular
uniform float _SpecPow;
uniform float _FresnelPow;
uniform float _EnvSpecInt;
uniform float _CubemapMip;
// Emission
uniform float _EmitInt;
// 输入结构
struct VertexInput {
float4 vertex : POSITION; //顶点信息Get
float2 uv0 : TEXCOORD0; //UV信息Get
float4 normal : NORMAL; //法线信息Get
float4 tangent : TANGENT; //切线信息
};
// 输出结构
struct VertexOutput {
float4 pos : SV_POSITION; //屏幕空间顶点位置
float2 uv0 : TEXCOORD0; //UV0
float4 posWS : TEXCOORD1; //世界空间顶点位置
float3 nDirWS : TEXCOORD2; //世界空间法线方向
float3 tDirWS : TEXCOORD3; //世界空间切线方向
float3 bDirWS : TEXCOORD4; //世界空间副切线方向
LIGHTING_COORDS(5,6)
};
// 顶点shader和像素shader实际上是两个函数 中间土黄色的名字是函数名
VertexOutput vert (VertexInput v) {
VertexOutput o = (VertexOutput)0;
o.pos = UnityObjectToClipPos( v.vertex );
o.uv0 = v.uv0;
o.posWS = mul(unity_ObjectToWorld,v.vertex); //顶点位置 OS
o.nDirWS = UnityObjectToWorldNormal(v.normal); // 法线方向 OS>WS
o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz); // 切线方向 OS>WS
o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w); // 副切线方向
TRANSFER_VERTEX_TO_FRAGMENT(o) // 投影相关
return o; // 返回输出结构
}
// 可以把float4理解为输出的一个RGBA的颜色信息
float4 frag(VertexOutput i) : COLOR {
// 准备向量
float3 nDirTS = UnpackNormal(tex2D(_NormTex , i.uv0)).rgb;
float3x3 TBN = float3x3(i.tDirWS , i.bDirWS , i.nDirWS);
float3 nDirWS = normalize(mul(nDirTS , TBN));
float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz);
float3 vrDirWS = reflect(vDirWS , nDirWS);
float3 lDirWS = _WorldSpaceLightPos0.xyz;
float3 lrDirWS = reflect(-lDirWS , nDirWS);
// 准备点积结果
float ndotl = dot(nDirWS , lDirWS); //Lambert
float vdotr = dot(vDirWS , lrDirWS); //Phong
float vdotn = dot(vDirWS , nDirWS); //CubeMap
// 采样纹理
float4 var_MainTex = tex2D(_MainTex , i.uv0);
float4 var_SpecTex = tex2D(_SpecTex , i.uv0);
float3 var_EmitTex = tex2D(_EmitTex, i.uv0).rgb;
float3 var_Cubemap = texCUBElod(_Cubemap, float4(vrDirWS, lerp(_CubemapMip, 0.0, var_SpecTex.a))).rgb;
// 光照模型(直接光照部分)
float3 baseCol = var_MainTex.rgb * _MainCol;
float lambert = max(0.0 , ndotl);
float specCol = var_SpecTex.rgb;
float specPow = lerp(1,_SpecPow , var_SpecTex.a);
float phong = pow(max(0.0 , vdotr) , specPow);
float shadow = LIGHT_ATTENUATION(i);
float3 dirLighting = (baseCol * lambert + specCol * phong) * _LightColor0 * shadow;
// 光照模型(环境光部分)
float upMask = max(0.0 , nDirWS.g);
float downMask = max(0.0 , -nDirWS.g);
float sideMask = 1.0 - upMask - downMask;
float3 envCol = _EnvUpCol * upMask + _EnvDownCol * downMask + _EnvSideCol * _EnvSideCol;
float frenel = pow(max(0.0 , 1.0 - vdotn) , _FresnelPow);
float occlusion = var_MainTex.a;
float3 envLighting = (baseCol * envCol * _EnvDiffInt + var_Cubemap * frenel * _EnvSpecInt * var_SpecTex.a) * occlusion;
// 光照模型(自发光部分)
float emitInt = _EmitInt * (sin(frac(_Time.z)) * 0.5 + 0.5);
float3 emission = var_EmitTex * emitInt;
float3 finalRGB = dirLighting + envLighting + emission;
return float4(finalRGB,1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}